Option Explicit

'------------------------------------------------
' Como: Leer y escribir archivos de tipo Random
' Puesto: 08-June-00
' Autor: Marcel Broesky
' Traductor: Daniel Quintero (dqrsoftware@gmx.net)
'
' Description: Código de ejemplo para leer y
' escribir hacia y desde archivos del tipo
' Random
'------------------------------------------------

Private Type empleado
   empID As Integer
   nombre As String * 30
   apellido As String * 20
   puesto As String * 20
End Type

Private Sub cmdLeer_Click()
Dim emp1 As empleado
Dim iFF As Integer
Dim i As Integer

   iFF = FreeFile
   Open App.Path & "\dat.dat" For Random As #iFF Len = Len(emp1)
   
   For i = 1 To 5
      
      Get #iFF, i, emp1
      
      txtCadena.Text = txtCadena.Text & "Name: " & Trim$(emp1.apellido) & " " & _
      Trim$(emp1.nombre) & vbCrLf & "puesto: " & Trim$(emp1.puesto) & _
      vbCrLf & "ID: " & Trim$(emp1.empID) & vbCrLf
   
   Next
   
   Close #iFF

End Sub

Private Sub cmdGuardar_Click()
Dim emp1 As empleado
Dim iFF As Integer
Dim i As Integer

   iFF = FreeFile
   Open App.Path & "\dat.dat" For Random As #iFF Len = Len(emp1)
   
   For i = 1 To 5
   
      With emp1
         .nombre = InputBox$("Enter Last Name")
         .apellido = InputBox$("Enter First Name")
         .puesto = InputBox$("Enter puesto")
         .empID = i
      End With
      
      Put #iFF, , emp1
   
   Next i
   
   Close #iFF
   
End Sub